建模問題實例解析

2017-11-02 by:CAE仿真在線來源:互聯網

最近ANSYS建模遇到了點小問題,折騰了好半天。現在終于搞清楚原由了,在這里分享一下,也許能幫到大家。也方便各位童鞋朋友以后遇到類似問題也好有個查錯思路。

所建模型是一個三維的線圈,處在長方體空氣區域里,為后面電磁場分析建立幾何模型。(空氣區域需要減去線圈所占的區域)。線型結構如下圖。

最初的建模命令如下:

/Prep7

pi=acos(-1) !定義圓周率pi

R=2 !線圈XY平面投影時中徑大小

R1=4 !線圈XZ投影是半徑大小

*do,i,0,16,1

*set,x,R*cos(i*pi/8)

*set,y,R*sin(i*pi/8)

*set,z,SQRT(R1*R1-(R*R*cos(i*pi/8)*cos(i*pi/8))) !定義XYZ坐標點

k,i+1,x,y,z

*enddo

*do,i,1,9,4

bsplin,i,i+1,i+2,i+3,i+4

*enddo

KDELE,17

bsplin,13,14,15,16,1 !定義樣條曲線

kwpave,1 !將工作平面原點移動到關鍵點1處

wpro,,90,

pcirc,0,0.1,0,360 !建立線圈截面

*do,j,1,4,1

vdrag,1+(j-1)*5,,,,,,j

*enddo !拉伸截面生成線圈實體

CM,COIL,VOLU !定義線圈組件COIL

VSEL,NONE

CSYS,0

WPAVE,0,0,0

CSYS,0

wpro,,-90, !轉換工作平面

BLOCK,-1.5*R,1.5*R,-1.5*R,1.5*R,0.5*R1,1.3*R1 !定義空氣區域

CM,AIR,VOLU

ALLSEL

VSBV,AIR,COIL,,DELE,KEEP !用線圈體減去空氣區域體

就在執行上面這條VSBV語句時出現問題:Topological degeneracy detected for vsbv command.try modifying geometry slightly or loosening the tolerance!

大致意思就是說:在執行VSBV命令時檢測到了拓撲退化,請嘗試稍微修改下幾何模型或者增大容差。容差放大后應該保證在后面的操作中恢復到默認設置。

但這個錯誤提示感覺沒多大用處嘛。沒有具體指出來哪里出錯了,ANSYS還是不夠智能哦。

然后就是一番百度查找問題所在,后面經專家指點才發現問題癥結。(感謝熱情的張老師J)!放大顯示線圈后看有一個地方是下圖這樣的結構!終于找到問題了,就是這里建模時出現了間隙與干涉,導致后面的布爾運算時顯示拓撲退化的提示!

后面的問題當然就是修改模型,把間隙與干涉處理掉。首先明白線圈的建模思路,先建立的16個關鍵點然后生成了4段樣條曲線,然后生成截面,然后拉伸截面形成線圈。分析得知這里的間隙是由于在間隙處的關鍵點兩邊的曲線在該點處的切線不共線。這里需要回到之前使用的樣條曲線命令bsplin上。查看help文檔,bsplin命令詳解如下所示。

前面6個點是用來指定樣條曲線經過的點。注意這里可以少于6個其他幾個點空著就行,但不能超過6個。后面幾個參數XV1,YV1,ZV1,XV6,YV6,ZV6是用來確定點1和點6處的切線矢量的。例如XV1,YV1,ZV1=(1,1,0)就代表在1點處的切線是XY平面內的45度方向。命令搞明白了,接著就修改上面的模型儂。

這里的目的就是要保證L1-L4線條在關鍵點1,5,9,14處切線共線。由于這四個關鍵點位置特殊,都為4個極點。所以方向矢量容易看出來。

下面是修改后的模型命令流。感興趣的朋友可以拷貝練練手。

/Prep7

pi=acos(-1)

R=2

R1=4

*do,i,0,16,1

*set,x,R*cos(i*pi/8)

*set,y,R*sin(i*pi/8)

*set,z,SQRT(R1*R1-(R*R*cos(i*pi/8)*cos(i*pi/8)))

k,i+1,x,y,z

*enddo

KDELE,17

bsplin,1,2,3,4,5,,0,-1,0,-1,0,0

bsplin,5,6,7,8,9,,1,0,0,0,-1,0

bsplin,9,10,11,12,13,,0,1,0,1,0,0

bsplin,13,14,15,16,1,,-1,0,0,0,1,0

kwpave,1

wpro,,90,

pcirc,0,0.1,0,360

*do,j,1,4,1

vdrag,1+(j-1)*5,,,,,,j

*enddo

CM,COIL,VOLU

VSEL,NONE

CSYS,0

WPAVE,0,0,0

CSYS,0

wpro,,-90,

BLOCK,-1.5*R,1.5*R,-1.5*R,1.5*R,0.5*R1,1.3*R1

CM,AIR,VOLU

ALLSEL

VSBV,AIR,COIL,,DELE,KEEP

修改后的線圈如下圖所示。這四段體相連接處都沒有間隙與干涉。VSBV布爾減操作時自然也沒有出現錯誤了。

最后小結一下:以后建模時遇到這樣錯誤提示Topological degeneracy detected for vsbv command.try modifying geometry slightly or loosening the tolerance! 建議首先將零部件放大放大在放大,看連接處有木有間隙或者干涉或者其它幾何結構缺陷!

開放分享：優質有限元技術文章,助你自學成才